/**
 * based on scrunch / flower generator
 * by Mitchell Whitelaw
 * http://openprocessing.org/visuals/?visualID=2615
 * 
 * Copyright (C) 2009 LAFKON/Benjamin Stephan.
 *
 * This is free software, and you may redistribute it under the GPL.
 * This Software comes with absolutely no warranty.
 * For details see the license (http://www.lafkon.net/gpl.txt)
 *
 * http://www.forkable.eu/generators/wtf/i/src/flg/0_01.pde
 */

import traer.physics.*;
import processing.pdf.*;

int howmanyframes,framecount,count,countstep;
int frameamount = 5;
boolean record = true;
boolean recording = false;
String outputdir = "tmp/";

ParticleSystem PS = new ParticleSystem(0.0, 0.5);
int pcount = 200;
int ring_radius = 100;
Particle[] Ring = new Particle[pcount];
Spring[] Innersprings = new Spring[pcount*2]; // two springs per particle
Spring[] Rim = new Spring[pcount];
float spokeStrength = 0.01;
float spokeDamping = 0.0;
float rimDamping = 0.01;
float rimStrength = 1.0;
float innerspring_length = ring_radius*2.5;

void setup(){
  size(400,400);
  background(255);
  smooth();
  buildParticles(PS);
  frameRate(2000);

  howmanyframes = int(loadStrings("tmp/gridsize.i")[0]);
  countstep = 500 / howmanyframes;   
}

void draw(){

  if(record == true && recording == false) {
    beginRecord(PDF, outputdir + "flg--" + nf(framecount,5) + ".pdf");
    recording = true;
    framecount++;
    count = 0;
    setup();
  }

  PS.tick(10.0/float(howmanyframes));

  translate(((height/2)),((width/2)));
  strokeWeight(0.5);
  stroke(0,0,0); 
  noFill();

  beginShape(LINES);
  for (int p=0; p<pcount;p++){
    vertex(Ring[p].position().x(),Ring[p].position().y());
  }
  endShape(CLOSE);

  // now shorten the springs
  for (int s=0; s<pcount; s++){
    int spr = int(random(pcount)); // note we only shorten half the springs (the first half)
    Innersprings[spr].setRestLength(Innersprings[spr].restLength() - random(0,2));
  }

  translate(((-height/2)),((-width/2)));

  if(recording == true && count == frameamount) {
    endRecord();
    frameamount += countstep;
    recording = false;
  } 

  if(recording == false && howmanyframes < framecount) { 
    exit(); 
  } 
  count++;  
}

void buildParticles(ParticleSystem P){
  for (float i=0; i<pcount; i++){ // makes the particles
    Ring[int(i)] = P.makeParticle(1.0,sin(TWO_PI*(i/pcount))*ring_radius,cos(TWO_PI*(i/pcount))*ring_radius,0);
  }
  float segmentlength = (TWO_PI*ring_radius)/float(pcount); // segment length

  for (int i=0; i<pcount; i++){ 
    Innersprings[i] =  P.makeSpring(Ring[i], Ring[int(random(pcount))],spokeStrength, spokeDamping, innerspring_length); // 2 random springs
    Innersprings[i+pcount] =  P.makeSpring(Ring[i], Ring[(i+int(random(pcount)))%pcount], spokeStrength, spokeDamping, innerspring_length); // between each point and 2 others
    if (i < pcount-1) {
      Rim[i] = P.makeSpring(Ring[i],Ring[i+1],rimStrength, rimDamping,segmentlength);
    }
    else { // join the last rim particle back to the first
      Rim[i] = P.makeSpring(Ring[i],Ring[0],rimStrength, rimDamping, segmentlength);
    }
  }
}